エクセルExcel大事典 VBAマクロアニメーション GIFアニメワークシート動画再生表示

GEN MUTO'S HOMEPAGE　＞　エクセル大事典　＞　エクセルVBAを極める

　■ エクセルVBAを極める－VBAスーパーテクニック

ワークシート上でアニメーションを表現してみよう！

　
■ ワークシートでアニメーション！

「エクセルのワークシート上の任意の場所でアニメーションを動かしたい！」
業務用のアプリケーションや趣味のフリーソフトの開発でそのような要望を持たれた方は少なくないと思います。

エクセルのワークシート上でGIFアニメを再生できれば簡単なのですが…。残念ながらワークシート上でGIFアニメを再生するのは無理なようです。

しかし、アニメーションを再生するのは実はそんなに難しいことではありません。ExcelVBAを使えば、簡単にあなたのワークシート上で、あらかじめ用意されたアニメーション画像を再生することが可能です。

今回はExcel2003とExcel2007の両方で、ワークシート上に透過GIFの画像をアニメーション再生してみましょう。
アニメーション用の透過GIF画像は、ご自身で用意してください。

Excel2003までなら…

Excel2003までなら、以下のマクロで簡単に任意の場所にGIF画像をアニメーション再生できます。

' モジュール宣言部に記述ここから－－－－－－－－－－－－－－－－－－－－－－－－－－
Public Declare Sub Sleep Lib "kernel32" (ByVal dwmilliseconds As Long)
' モジュール宣言部に記述ここまで－－－－－－－－－－－－－－－－－－－－－－－－－－

Public Sub test()
Dim WrkPicture(9) As Picture
Dim i As Long
　　For i = 0 To 9
　　　　Set WrkPicture(i) = ActiveSheet.Pictures.Insert(LCase(ThisWorkbook.Path _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　& "\img\" & i & ".gif"))
　　　　If i <> 0 Then
　　　　　　WrkPicture(i - 1).Delete
　　　　　　Set WrkPicture(i - 1) = Nothing
　　　　End If
　　　　Call Sleep (100)
　　　　DoEvents
　　Next i
　　WrkPicture(i - 1).Delete
　　Set WrkPicture(i - 1) = Nothing
End Sub

まず、アニメーション用の透過GIF画像を10枚用意します。GIF画像のファイル名は0.gif～9.gifとします。
次に実行するマクロブックのある場所に"img"というフォルダを作り、その中にGIF画像を格納します。
これで準備は完了です。上記マクロを実行してみましょう。

Excel2003までなら、アクティブセルのそばに用意されたGIF画像が連続して現れ、10枚目の画像が表示されたあと、画像が消えるはずです。

マクロの中を詳しく見ていきましょう。

まず、宣言部でAPIのSleep関数を定義しています。これは、アニメーションの再生にウェイトをかける必要があるためです。（ウェイトをかけないと、一瞬でアニメーションが再生され、わけがわかりません）
今回は、0.1秒間隔（Call Sleep (100)）で10枚の画像を表示させるので、アニメーションの再生時間は1秒になります。

Pictureオブジェクトで定義した配列、WrkPicture(9)に用意したGIF画像を0.gifから順番に画像挿入していきます。
WrkPicture(1)が挿入された時点で、その下にWrkPicture(0)がまだ残っています。これを消さないと、画像がどんどん上に重なっていきますので、2回目以降のループで消しています。

わざわざこんなことをしているのは、このほうがアニメーションの再生が滑らかになるからです。
（次の画像を重ねる前に下の画像を消すと、アニメーションがブチブチになります）
もちろん忘れずに、DoEventsで画像更新をしてやる必要もあります。

ループを抜けた後の画像クリアは必要に応じて、使い分けてください。画像をそのまま残すならこの部分の処理は必要ありません。

さて、せっかくですので、ワークシートのセレクションチェンジイベントからCallさせてみましょう。

' ワークシートモジュールに記述ここから－－－－－－－－－－－－－－－－－－－－－－－
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
　　Call test
End Sub
' ワークシートモジュールに記述ここまで－－－－－－－－－－－－－－－－－－－－－－－

これで、Excel2003までなら、アクティブセルを変更するたびに、アクティブセルのそばでアニメーション画像を再生してくれるはずです。

Excel2007だとどうなる？

さてこのマクロブックを、Excel2007の互換モードで開いてみましょう。
マクロを実行してみるとすぐにわかりますが、アニメーションの表示位置がExcel2003とは異なります。
Excel2003ではアクティブセルの位置に画像を挿入してくれたのに、Excel2007ではアクティブセルとは無関係に、ワークシートの左上部に表示されます。
どうも、Excel2007では画像の挿入に関する内部の仕組みが変わってしまったようです。
まあ、この場合、
　　WrkPicture(i).Top = Selection.Top
　　WrkPicture(i).Left = Selection.Left
を追加して、画像の表示位置を指定することもできますが、プログラムの実行速度が遅いと、移動させる画像が残像になって表示され大変見苦しくなってしまいます。

ここで、もうひとつのワークシート上で画像をアニメーションさせる方法をご紹介します。

Public Sub test()
Dim WrkRange As ShapeRange
Dim i As Long
　　For i = 0 To 9
　　　　Set WrkRange = ActiveSheet.Shapes.Range("animation")
　　　　　　WrkRange.Fill.UserPicture LCase(ThisWorkbook.Path _
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　& "\img\" & i & ".gif")
　　　　Set WrkRange = Nothing
　　　　Call Sleep(100)
　　　　DoEvents
　　Next i
　　Set WrkRange = ActiveSheet.Shapes.Range("animation")
　　　　WrkRange.Fill.Visible = msoFalse
　　Set WrkRange = Nothing
End Sub

今回は、ShapeRangeオブジェクトを使ってアニメーションを表示させています。
前回の方法が画像を次々挿入してアニメーションさせていたのに対し、今回はあらかじめ表示させる画像オブジェクトを用意しておき（ActiveSheet.Shapes.Range("animation")の部分）その背景画像を書き換えるという方法をとっています。

まず、アニメーションさせる画像と同じ大きさの矩形オートシェイプをワークシートに挿入し、表示させたい場所に移動します。次に、図の書式設定で塗りつぶしを"塗りつぶしなし"、線を"線なし"に指定します。最後に、挿入したオートシェイプの名前を"animation"に変更します。これで準備ＯＫです。

早速、マクロを実行してみましょう。
画像オブジェクト"animation"の背景画像が次々と読み込まれ、アニメーションしている様子がご覧になれたと思います。

このマクロでは、アクティブシート上にある"animation"という名前のオブジェクトでShapeRangeオブジェクトを生成しています。あとは、ループ処理でその背景画像を、Fill.UserPicture プロパティを用いて、表示させたいGIF画像に次々と変更させます。

最後に、Fill.Visible = msoFalse で塗りつぶしなしにしていますが、前回と同様に、画像をそのまま残すならこの部分の処理は必要ありません。

さらに、前回同様、ワークシートのセレクションチェンジイベントで、このマクロをCallさせてみましょう。

' ワークシートモジュールに記述ここから－－－－－－－－－－－－－－－－－－－－－－－
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim WrkRange As ShapeRange
　　Set WrkRange = ActiveSheet.Shapes.Range("animation")
　　　　WrkRange.Top = Target.Top
　　　　WrkRange.Left = Target.Left
　　Set WrkRange = Nothing
　　Call test
End Sub
' ワークシートモジュールに記述ここまで－－－－－－－－－－－－－－－－－－－－－－－

これで、前回同様、アクティブセルの位置に合わせてアニメーション画像が表示されるはずです。画像オブジェクトの移動は、このとき一度きりなので、見苦しい残像が発生する恐れもありません。

ちなみに、拙作ソフトのCell_雀ver3.20では、この方法を用いてExcel2007上で冴子先生等オフィスアシスタントのアニメーションを再現させています。興味のある方はぜひお試しください。

ワークシート上でアニメーションを自在に行えれば、エクセルを用いて簡単なプレゼンテーションを行ったり、ユーザーと対話させるなど、インタラクティブで楽しいアプリケーションを開発することが可能になります。

ぜひ、皆さんも挑戦してみてください。

＞＞次の話にすすむ

サイト内検索ができます

Microsoft Most Valuable Professional

Microsoft MVP Excel
武藤玄プロフィール
　

■■■ 執筆した書籍 ■■■
　

EXCEL VBA 業務自動化
　

 Excel VBA を５日でマスターする本
　

 仕事を速くする Excel VBA 入門
　

 Excel VBAと業務改善のポイントがわかる本
　

 Access VBA ベーシックスタンダード
　

 Excel VBA アクションゲーム作成入門
　

■■■ 連載中の記事 ■■■
　

Excel VBAで業務改善！
　

実務で使うExcel VBA
　

■ ＴＯＰページ

■ エクセルVBA超入門

　・９ステップで"Hello World!"
　　からオブジェクト指向まで！
　　1."Hello World!"を表示しよう
　　2.基本はデータの入出力
　　3.繰り返し処理
　　4.シートで簡易データベース
　　5.名前をつけよう
　　6.構造化プログラムに挑戦
　　7.構造体を使ってみよう
　　8.フォームを使ってみよう
　　9.オブジェクト指向に挑戦

エクセルExcel大事典ははリンクフリーです
お問い合わせはこちら gengengen@yahoo.co.jp